Function GetADdescription()

Die Funktion GetADdescription() ist eine Beispielfunktion, in der die Property Description für ein Computerobjekt abgefragt werden kann.

Function GetADdescription(strDomainDN, strServer)
    ON ERROR RESUME NEXT
    Dim strBase, strFilter, StrAttrs, strScope, strComputerDesc
    Dim objConn, objRS

    strBase = "<LDAP://" & strDomainDN & ">;"
    strFilter = "(&(objectCategory=computer)(cn=" & strServer & "));"
    strAttrs = "description" & ";"
    strScope = "subTree"

    GetADdescription=""
    set objConn = CreateObject("ADODB.Connection")
    objConn.Provider = "ADsDSOObject"
    objConn.Open "Active Directory Provider"

    Err.clear
    set objRS = objConn.Execute(strBase & strFilter & strAttrs & strScope)
    If Err.Number Then
        PrintLog Err.Number, strServer & ": ERROR ADODB at Set objRS = objConn.Execute(" & strBase & strFilter & strAttrs & strScope & ")"
        Err.Clear
        GetADdescription = "ERROR ADODB"
        Exit Function
    End If
    objRS.MoveFirst
    While Not objRS.EOF
        strComputerDesc = objRS.Fields("description").Value 'wird als Variant Array zurückgeliefert !?
        GetADdescription = strComputerDesc(0)
        objRS.MoveNext
    Wend
End Function

Als Returnwert von GetADdescription() bekommen wir einen String mit dem Wert der Property "Description" des abgefragten Objekts.

Die Property Description gibt es für alle AD Objekte, wie User, Gruppen, Computer, OUs etc.
Wenn mit obigem Skript nach User Objekten gesucht werden soll, dann muss lediglich der Filter objectCategory=computer in objectCategory=user und natürlich der CN=Suchstring geändert werden.

Aufrufbeispiel:
strDescrp = GetADdescription(GetDomainDN(), "Server01")


AD - Scripting Basics